;;; unicon.el --- mode for editing Unicon code

;; Copyright (C) 1989 Free Software Foundation, Inc.

;; Author: Robert Parlett <parlett@dial.pipex.com>
;;         -very substantially based on icon.el by
;;          Chris Smith <csmith@convex.com>
;; Created: 15 Mar 99
;; Keywords: languages

;; This file is part of XEmacs.

;; XEmacs is free software; you can redistribute it and/or modify it
;; under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; XEmacs is distributed in the hope that it will be useful, but
;; WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
;; General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with XEmacs; see the file COPYING.  If not, write to the Free
;; Software Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
;; 02111-1307, USA.

;;; Synched up with: FSF 19.34.

;;; Commentary:

;; A major mode for editing the Unicon programming language.

;;; Code:

;;; History:
;;; 12-6-99   Fixed handling of variables called end_???, if_??? and else_???
;;;
(defvar unicon-mode-abbrev-table nil
  "Abbrev table in use in Unicon-mode buffers.")
(define-abbrev-table 'unicon-mode-abbrev-table ())

(defvar unicon-mode-map ()
  "Keymap used in Unicon mode.")
(if unicon-mode-map
    ()
  (setq unicon-mode-map (make-sparse-keymap))
  (define-key unicon-mode-map "\r" 'electric-unicon-terminate-line)
  (define-key unicon-mode-map "{" 'electric-unicon-brace)
  (define-key unicon-mode-map "}" 'electric-unicon-brace)
  (define-key unicon-mode-map "\e\C-h" 'mark-unicon-function)
  (define-key unicon-mode-map "\e\C-a" 'beginning-of-unicon-defun)
  (define-key unicon-mode-map "\e\C-e" 'end-of-unicon-defun)
  (define-key unicon-mode-map "\e\C-q" 'indent-unicon-exp)
  (define-key unicon-mode-map "\177" 'backward-delete-char-untabify)
  (define-key unicon-mode-map "\t" 'unicon-indent-command))

(defvar unicon-mode-syntax-table nil
  "Syntax table in use in Unicon-mode buffers.")

(if unicon-mode-syntax-table
    ()
  (setq unicon-mode-syntax-table (make-syntax-table))
  (modify-syntax-entry ?\\ "\\" unicon-mode-syntax-table)
  (modify-syntax-entry ?# "<" unicon-mode-syntax-table)
  (modify-syntax-entry ?\n ">" unicon-mode-syntax-table)
  (modify-syntax-entry ?$ "." unicon-mode-syntax-table)
  (modify-syntax-entry ?/ "." unicon-mode-syntax-table)
  (modify-syntax-entry ?* "." unicon-mode-syntax-table)
  (modify-syntax-entry ?+ "." unicon-mode-syntax-table)
  (modify-syntax-entry ?- "." unicon-mode-syntax-table)
  (modify-syntax-entry ?= "." unicon-mode-syntax-table)
  (modify-syntax-entry ?% "." unicon-mode-syntax-table)
  (modify-syntax-entry ?< "." unicon-mode-syntax-table)
  (modify-syntax-entry ?> "." unicon-mode-syntax-table)
  (modify-syntax-entry ?& "." unicon-mode-syntax-table)
  (modify-syntax-entry ?| "." unicon-mode-syntax-table)
  (modify-syntax-entry ?\' "\"" unicon-mode-syntax-table))

(defvar unicon-indent-use-only-spaces nil
  "*Non-nil means use only spaces when indenting; otherwise use spaces and tabs.")
(defvar unicon-indent-level 4
  "*Indentation of Unicon statements with respect to containing block.")
(defvar unicon-class-indent-level 4
  "*Indentation of methods within classes.")
(defvar unicon-brace-imaginary-offset 0
  "*Imagined indentation of a Unicon open brace that actually follows a statement.")
(defvar unicon-brace-offset 0
  "*Extra indentation for braces, compared with other text in same context.")
(defvar unicon-continued-statement-offset 4
  "*Extra indent for lines not starting new statements.")
(defvar unicon-continued-brace-offset 0
  "*Extra indent for substatements that start with open-braces.
This is in addition to unicon-continued-statement-offset.")

(defvar unicon-auto-newline nil
  "*Non-nil means automatically newline before and after braces
inserted in Unicon code.")

(defvar unicon-electric-newline nil
  "*Non-nil means automatically indent current and new line whenever
return is pressed.")

(defvar unicon-tab-always-indent t
  "*Non-nil means TAB in Unicon mode should always reindent the current line,
regardless of where in the line point is when the TAB command is used.")

;;;###autoload
(defun unicon-mode ()
  "Major mode for editing Unicon code.
Expression and list commands understand all Unicon brackets.
Tab indents for Unicon code.
Paragraphs are separated by blank lines only.
Delete converts tabs to spaces as it moves back.
\\{unicon-mode-map}
Variables controlling indentation style:
 unicon-tab-always-indent
    Non-nil means TAB in Unicon mode should always reindent the current line,
    regardless of where in the line point is when the TAB command is used.
 unicon-auto-newline
    Non-nil means automatically newline before and after braces
    inserted in Unicon code.
 unicon-indent-level
    Indentation of Unicon statements within surrounding block.
    The surrounding block's indentation is the indentation
    of the line on which the open-brace appears.
 unicon-continued-statement-offset
    Extra indentation given to a substatement, such as the
    then-clause of an if or body of a while.
 unicon-continued-brace-offset
    Extra indentation given to a brace that starts a substatement.
    This is in addition to `unicon-continued-statement-offset'.
 unicon-brace-offset
    Extra indentation for line if it starts with an open brace.
 unicon-brace-imaginary-offset
    An open brace following other text is treated as if it were
    this far to the right of the start of its line.

Turning on Unicon mode calls the value of the variable `unicon-mode-hook'
with no args, if that value is non-nil."
  (interactive)
  (kill-all-local-variables)
  (use-local-map unicon-mode-map)
  (setq major-mode 'unicon-mode)
  (setq mode-name "Unicon")
  (setq local-abbrev-table unicon-mode-abbrev-table)
  (set-syntax-table unicon-mode-syntax-table)
  (make-local-variable 'paragraph-start)
  (setq paragraph-start (concat "$\\|" page-delimiter))
  (make-local-variable 'paragraph-separate)
  (setq paragraph-separate paragraph-start)
  (make-local-variable 'indent-line-function)
  (setq indent-line-function 'unicon-indent-line)
  (make-local-variable 'require-final-newline)
  (setq require-final-newline t)
  (make-local-variable 'comment-start)
  (setq comment-start "# ")
  (make-local-variable 'comment-end)
  (setq comment-end "")
  (make-local-variable 'comment-column)
  (setq comment-column 32)
  (make-local-variable 'comment-start-skip)
  (setq comment-start-skip "# *")
  (make-local-variable 'comment-indent-function)
  (setq comment-indent-function 'unicon-comment-indent)
  (run-hooks 'unicon-mode-hook))

;; This is used by indent-for-comment to decide how much to
;; indent a comment in Unicon code based on its context.
(defun unicon-comment-indent ()
  (if (looking-at "^#")
      0	
    (save-excursion
      (skip-chars-backward " \t")
      (max (if (bolp) 0 (1+ (current-column)))
	   comment-column))))

(defun electric-unicon-brace (arg)
  "Insert character and correct line's indentation."
  (interactive "P")
  (let (insertpos)
    (if (and (not arg)
	     (eolp)
	     (or (save-excursion
		   (skip-chars-backward " \t")
		   (bolp))
		 (if unicon-auto-newline
		     (progn (unicon-indent-line) (newline) t)
		   nil)))
	(progn
	  (insert last-command-char)
	  (unicon-indent-line)
	  (if unicon-auto-newline
	      (progn
		(newline)
		;; (newline) may have done auto-fill
		(setq insertpos (- (point) 2))
		(unicon-indent-line)))
	  (save-excursion
	    (if insertpos (goto-char (1+ insertpos)))
	    (delete-char -1))))
    (if insertpos
	(save-excursion
	  (goto-char insertpos)
	  (self-insert-command (prefix-numeric-value arg)))
      (self-insert-command (prefix-numeric-value arg)))))

(defun unicon-indent-command (&optional whole-exp)
  (interactive "P")
  "Indent current line as Unicon code, or in some cases insert a tab character.
If `unicon-tab-always-indent' is non-nil (the default), always indent current
line.  Otherwise, indent the current line only if point is at the left margin
or in the line's indentation; otherwise insert a tab.

A numeric argument, regardless of its value, means indent rigidly all the
lines of the expression starting after point so that this line becomes
properly indented.  The relative indentation among the lines of the
expression are preserved."
  (if whole-exp
      ;; If arg, always indent this line as Unicon
      ;; and shift remaining lines of expression the same amount.
      (let ((shift-amt (unicon-indent-line))
	    beg end)
	(save-excursion
	  (if unicon-tab-always-indent
	      (beginning-of-line))
	  (setq beg (point))
	  (forward-sexp 1)
	  (setq end (point))
	  (goto-char beg)
	  (forward-line 1)
	  (setq beg (point)))
	(if (> end beg)
	    (indent-code-rigidly beg end shift-amt "#")))
    (if (and (not unicon-tab-always-indent)
	     (save-excursion
	       (skip-chars-backward " \t")
	       (not (bolp))))
	(insert-tab)
      (unicon-indent-line))))

(defun unicon-indent-line ()
  "Indent current line as Unicon code.
Return the amount the indentation changed by."
  (let ((indent (calculate-unicon-indent nil))
	beg shift-amt
	(case-fold-search nil)
	(pos (- (point-max) (point))))
    (beginning-of-line)
    (setq beg (point))
    (cond ((eq indent nil)
	   (setq indent (current-indentation)))
	  ((eq indent t)
	   (setq indent (calculate-unicon-indent-within-comment)))
	  ((looking-at "[ \t]*#")
	   ())        ;; rpp - was  (setq indent 0))
	  (t
	   (skip-chars-forward " \t")
	   (if (listp indent) (setq indent (car indent)))
	   (cond ((and (looking-at "else\\b")
		       (not (looking-at "else\\s_")))
		  (setq indent (save-excursion
				 (unicon-backward-to-start-of-if)
				 (current-indentation))))
		 ((and (looking-at "end\\b")
		       (not (looking-at "end\\s_")))
		  (setq indent unicon-end-indent-level))

		 ((= (following-char) ?})
		  (setq indent (- indent unicon-indent-level)))

		 ((= (following-char) ?{)
		  (setq indent (+ indent unicon-brace-offset))))))
    (skip-chars-forward " \t")
    (setq shift-amt (- indent (current-column)))
    (if (zerop shift-amt)
	(if (> (- (point-max) pos) (point))
	    (goto-char (- (point-max) pos)))
      (delete-region beg (point))
      (indent-to-spaces indent)
      ;; If initial point was within line's indentation,
      ;; position after the indentation.  Else stay at same point in text.
      (if (> (- (point-max) pos) (point))
	  (goto-char (- (point-max) pos))))
    shift-amt))

(defun calculate-unicon-indent (&optional parse-start)
  "Return appropriate indentation for current line as Unicon code.
In usual case returns an integer: the column to indent to.
Returns nil if line starts inside a string, t if in a comment."
  (save-excursion
    (beginning-of-line)
    (let ((indent-point (point))
	  (case-fold-search nil)
	  (line-no (count-lines 1 (point)))
	  containing-sexp-line
	  state
	  containing-sexp
	  toplevel)
      (if parse-start
	  (goto-char parse-start)
	(setq toplevel (beginning-of-unicon-defun)))
      (while (< (point) indent-point)
	(setq parse-start (point))
	(setq state (parse-partial-sexp (point) indent-point 0))
	(setq containing-sexp (car (cdr state))))
      (cond ((or (nth 3 state) (nth 4 state))
	     ;; return nil or t if should not change this line
	     (nth 4 state))
	    ((and containing-sexp
		  (/= (char-after containing-sexp) ?{))
	     ;; line is expression, not statement:
	     (setq containing-sexp-line (count-lines 1 containing-sexp))
	     (if (= line-no containing-sexp-line)
		 (goto-char (1+ containing-sexp))

	         (progn
		   (forward-line -1)
		   (beginning-of-line)
		   (skip-chars-forward " \t")
                 )
              )
	     (current-column)
	     )
	    (t
	     (if toplevel
		 ;; Outside any procedures.
		 (progn (unicon-backward-to-noncomment (point-min))
			(if (unicon-is-continuation-line)
			    unicon-continued-statement-offset unicon-extra-indent))
	       ;; Statement level.
	       (if (null containing-sexp)
		   (progn (beginning-of-unicon-defun)
			  (setq containing-sexp (point))))
	       (goto-char indent-point)
	       ;; Is it a continuation or a new statement?
	       ;; Find previous non-comment character.
	       (unicon-backward-to-noncomment containing-sexp)
	       ;; Now we get the answer.
	       (if (unicon-is-continuation-line)
		   ;; This line is continuation of preceding line's statement;
		   ;; indent  unicon-continued-statement-offset  more than the
		   ;; first line of the statement.
		   (progn
		     (unicon-backward-to-start-of-continued-exp containing-sexp)
		     (+ unicon-continued-statement-offset (current-column)
			(if (save-excursion (goto-char indent-point)
					    (skip-chars-forward " \t")
					    (eq (following-char) ?{))
			    unicon-continued-brace-offset 0)))
		 ;; This line starts a new statement.
		 ;; Position following last unclosed open.
		 (goto-char containing-sexp)
		 ;; Is line first statement after an open-brace?
		 (or
		  ;; If no, find that first statement and indent like it.
		  (save-excursion
		  (cond
                      ((looking-at "procedure\\s \\|method\\s ")
                          (forward-sexp 3))
		      ((looking-at "initially\\s *\\s(")
		          (forward-sexp 2))
		      ((looking-at "initially")
		          (end-of-line))
		      (t  (forward-char 1))
                  )

		  (while (progn (skip-chars-forward " \t\n")
				(looking-at "#"))
		    ;; Skip over comments following openbrace.
		    (forward-line 1))
		  ;; The first following code counts
		  ;; if it is before the line we want to indent.
		  (and (< (point) indent-point)
		       (current-column)))
		  ;; If no previous statement,
		  ;; indent it relative to line brace is on.
		  ;; For open brace in column zero, don't let statement
		    ;; start there too.  If unicon-indent-level is zero,
		    ;; use unicon-brace-offset + unicon-continued-statement-offset
		    ;; instead.
		    ;; For open-braces not the first thing in a line,
		    ;; add in unicon-brace-imaginary-offset.
		    (+ (if (and (bolp) (zerop unicon-indent-level))
			   (+ unicon-brace-offset
			      unicon-continued-statement-offset)
			 unicon-indent-level)
		       ;; Move back over whitespace before the openbrace.
		       ;; If openbrace is not first nonwhite thing on the line,
		       ;; add the unicon-brace-imaginary-offset.
		       (progn (skip-chars-backward " \t")
			      (if (bolp) 0 unicon-brace-imaginary-offset))
		       ;; Get initial indentation of the line we are on.
		       (current-indentation))))))))))

;; List of words to check for as the last thing on a line.
;; If cdr is t, next line is a continuation of the same statement,
;; if cdr is nil, next line starts a new (possibly indented) statement.

(defconst unicon-resword-alist
  '(("by" . t) ("case" . t) ("create") ("do") ("dynamic" . t) ("else")
    ("every" . t) ("if" . t) ("global" . t) ("initial" . t)
    ("link" . t) ("local" . t) ("of") ("record" . t) ("repeat" . t)
    ("static" . t) ("then") ("to" . t) ("until" . t) ("while" . t)))

(defun unicon-is-continuation-line ()
  (let* ((ch (preceding-char))
	 (ch-syntax (char-syntax ch)))
    (if (eq ch-syntax ?w)
	(assoc (buffer-substring
		(progn (forward-word -1) (point))
		(progn (forward-word 1) (point)))
	       unicon-resword-alist)
      (not (memq ch '(0 ?\; ?\} ?\{ ?\) ?\] ?\" ?\' ?\n))))))

(defun unicon-backward-to-noncomment (lim)
  (let (opoint stop)
    (while (not stop)
      (skip-chars-backward " \t\n\f" lim)
      (setq opoint (point))
      (beginning-of-line)
      ;;; rpp
      ;;; fixed bug here, changed 5 to 4 (inside comment)
      (if (and (nth 4 (parse-partial-sexp (point) opoint))
	       (< lim (point)))
	  (search-backward "#")
	(setq stop t))
      )
   )
)

(defun unicon-backward-to-start-of-continued-exp (lim)
  (if (memq (preceding-char) '(?\) ?\]))
      (forward-sexp -1))
  (beginning-of-line)
  (skip-chars-forward " \t")
  (cond
;;   ((<= (point) lim) (goto-char (+ unicon-indent-level lim)))
   ((<= (point) lim) (goto-char (1+ lim)))
   ((not (unicon-is-continued-line)) 0)
   ((and (eq (char-syntax (following-char)) ?w)
	 (cdr
	  (assoc (buffer-substring (point)
				   (save-excursion (forward-word 1) (point)))
		 unicon-resword-alist))) 0)
   (t (end-of-line 0) (unicon-backward-to-start-of-continued-exp lim))))

(defun unicon-is-continued-line ()
  (save-excursion
    (end-of-line 0)
    (unicon-is-continuation-line)))

(defun unicon-backward-to-start-of-if (&optional limit)
  "Move to the start of the last \"unbalanced\" if."
  (or limit (setq limit (save-excursion (beginning-of-unicon-defun) (point))))
  (let ((if-level 1)
	(case-fold-search nil))
    (while (not (zerop if-level))
      (backward-sexp 1)
      (cond ((and (looking-at "else\\b")
		  (not (looking-at "else\\s_")))
	     (setq if-level (1+ if-level)))
	    ((and (looking-at "if\\b")
		  (not (looking-at "if\\s_")))
	     (setq if-level (1- if-level)))
	    ((< (point) limit)
	     (setq if-level 0)
	     (goto-char limit))))))

(defun mark-unicon-function ()
  "Put mark at end of Unicon function, point at beginning."
  (interactive)
  (push-mark (point))
  (end-of-unicon-defun)
  (push-mark (point))
  (beginning-of-line 0)
  (beginning-of-unicon-defun))


(defun beginning-of-unicon-defun ()
  "Go to the start of the enclosing procedure; return t if at top level."
  (interactive)
  (cond
      ((re-search-backward "^\\s *procedure\\s \\|^\\s *initially\\s *$\\|^\\s *initially\\s *\\s(.*$\\|^\\s *method\\s \\|^class\\s \\|^\\s *end\\s *$" (point-min) 'move)
         (skip-chars-forward " \t")
         (cond
            ((looking-at "c")
               (setq unicon-extra-indent unicon-class-indent-level)
	       (setq unicon-end-indent-level 0)
               t
            )
            ((looking-at "e")
	       (setq unicon-extra-indent (current-column))
	       (setq unicon-end-indent-level 0)
               t
	    )
            ((looking-at "i")
	       (setq unicon-end-indent-level 0)
               nil
            )
            (t
	       (setq unicon-extra-indent (current-column))
	       (setq unicon-end-indent-level (current-column))
               nil
            )
         )
      )
      (t
         (setq unicon-extra-indent 0)
         t
      )
   )
)

(defun end-of-unicon-defun ()
  (interactive)
  (if (not (bobp)) (forward-char -1))
  (re-search-forward "^\\s *end\\s *$" (point-max) 'move)
  (forward-word -1)
  (forward-line 1))

(defun indent-unicon-exp ()
  "Indent each line of the Unicon grouping following point."
  (interactive)
  (let ((indent-stack (list nil))
	(contain-stack (list (point)))
	(case-fold-search nil)
	restart outer-loop-done inner-loop-done state ostate
	this-indent last-sexp
	at-else at-brace at-do
	(opoint (point))
	(next-depth 0))
    (save-excursion
      (forward-sexp 1))
    (save-excursion
      (setq outer-loop-done nil)
      (while (and (not (eobp)) (not outer-loop-done))
	(setq last-depth next-depth)
	;; Compute how depth changes over this line
	;; plus enough other lines to get to one that
	;; does not end inside a comment or string.
	;; Meanwhile, do appropriate indentation on comment lines.
	(setq innerloop-done nil)
	(while (and (not innerloop-done)
		    (not (and (eobp) (setq outer-loop-done t))))
	  (setq ostate state)
	  (setq state (parse-partial-sexp (point) (progn (end-of-line) (point))
					  nil nil state))
	  (setq next-depth (car state))
	  (if (and (car (cdr (cdr state)))
		   (>= (car (cdr (cdr state))) 0))
	      (setq last-sexp (car (cdr (cdr state)))))
	  (if (or (nth 4 ostate))
	      (unicon-indent-line))
	  (if (or (nth 3 state))
	      (forward-line 1)
	    (setq innerloop-done t)))
	(if (<= next-depth 0)
	    (setq outer-loop-done t))
	(if outer-loop-done
	    nil
	  (if (/= last-depth next-depth)
	      (setq last-sexp nil))
	  (while (> last-depth next-depth)
	    (setq indent-stack (cdr indent-stack)
		  contain-stack (cdr contain-stack)
		  last-depth (1- last-depth)))
	  (while (< last-depth next-depth)
	    (setq indent-stack (cons nil indent-stack)
		  contain-stack (cons nil contain-stack)
		  last-depth (1+ last-depth)))
	  (if (null (car contain-stack))
	      (setcar contain-stack (or (car (cdr state))
					(save-excursion (forward-sexp -1)
							(point)))))
	  (forward-line 1)
	  (skip-chars-forward " \t")
	  (if (eolp)
	      nil
	    (if (and (car indent-stack)
		     (>= (car indent-stack) 0))
		;; Line is on an existing nesting level.
		;; Lines inside parens are handled specially.
		(if (/= (char-after (car contain-stack)) ?{)
		    (setq this-indent (car indent-stack))
		  ;; Line is at statement level.
		  ;; Is it a new statement?  Is it an else?
		  ;; Find last non-comment character before this line
		  (save-excursion
		    (setq at-else (looking-at "else\\W"))
		    (setq at-brace (= (following-char) ?{))
		    (unicon-backward-to-noncomment opoint)
		    (if (unicon-is-continuation-line)
			;; Preceding line did not end in comma or semi;
			;; indent this line  unicon-continued-statement-offset
			;; more than previous.
			(progn
			  (unicon-backward-to-start-of-continued-exp (car contain-stack))
			  (setq this-indent
				(+ unicon-continued-statement-offset (current-column)
				   (if at-brace unicon-continued-brace-offset 0))))
		      ;; Preceding line ended in comma or semi;
		      ;; use the standard indent for this level.
		      (if at-else
			  (progn (unicon-backward-to-start-of-if opoint)
				 (setq this-indent (current-indentation)))
			(setq this-indent (car indent-stack))))))
	      ;; Just started a new nesting level.
	      ;; Compute the standard indent for this level.
	      (let ((val (calculate-unicon-indent
			   (if (car indent-stack)
			       (- (car indent-stack))))))
		(setcar indent-stack
			(setq this-indent val))))
	    ;; Adjust line indentation according to its contents
	    (if (or (= (following-char) ?})
		    (and (looking-at "end\\b")
			 (not (looking-at "end\\s_")))
			 )
		(setq this-indent (- this-indent unicon-indent-level)))
	    (if (= (following-char) ?{)
		(setq this-indent (+ this-indent unicon-brace-offset)))
	    ;; Put chosen indentation into effect.
	    (or (= (current-column) this-indent)
		(progn
		  (delete-region (point) (progn (beginning-of-line) (point)))
		  (indent-to-spaces this-indent)))
	    ;; Indent any comment following the text.
	    (or (looking-at comment-start-skip)
		(if (re-search-forward comment-start-skip (save-excursion (end-of-line) (point)) t)
		    (progn (indent-for-comment) (beginning-of-line))))))))))


(defun indent-to-spaces (n)
  (if unicon-indent-use-only-spaces
     (while (< (current-column) n)
       (insert " ")
     )

     (indent-to n)
  )
)

(defun electric-unicon-terminate-line ()
  "Terminate line and indent next line."
  (interactive)
  (if unicon-electric-newline
      (progn
         (save-excursion
	    (unicon-indent-line)
         )
         (newline)
         ;; Indent next line
         (unicon-indent-line)
      )
      (newline)
   )
)

;;; unicon.el ends here